Building gadgets using the Arduino.
After building the solar tracker, I was excited to play with the Arduino some more so I bought this Arduino starter kit. It comes with many sensors, controllers, motors and other electrical devices as well as project instructions to use them.
Sassu really wanted to build a project using the fan and so we built the one that came with the kit. Like before, I ran into power issues and so I finally figured out why Arduino kits came with little power supplies; you can run very little off the Arduino board itself. These power supplies are very cool because they fit right on the bread board to provide power to the outer strips.
Another problem I had was that the instructions did not have a common ground between the Arduino and the bread board with the motor controller so things were acting very flaky. I added the common ground and then things worked better. Still, I found that one orientation of the L293D motor controller did not spin the fan as fast as the other orientation. Is this chip not symmetric?
To soup it up a little, I decided we should add a remote control. The kit comes with a remote control sensor and controller and so I added it. I put the IR sensor on the same bread board as the motor controller and again things got flaky! I added a second bread board with its own power supply and things worked okay. (Geez, do I need a separate power supply for every component in my project? I'm still not sure.)
I programmed the control's power, reverse, fast forward, volume up, volume down and number keys to control the fan's power, direction and speed. Unfortunately, the control has a super short range so you have to hold it right by the sensor. That and no feedback except from the fan made it frustrating for Ella so I decided to add a power indicator so at least the power button would have good feedback.
I decided to use the RGB LED that comes with the kit for my power indicator. When the power is off, I wanted it to glow red and when the power is on, I wanted it to cycle through many colors. So I looked at the instruction for this and added it.
Annoyingly, the RGB LED worked perfectly by itself but when I integrated it with everything else it acted very oddly. After much head scratching and code exploration, I found out that the IRRemote library that comes with the kit secretly sets the Arduino's pin 9 for some timer function. Since I was using pin 9 for the RGB LED this caused it not to work. I changed the pin assignments and then everything started working as expected. Why is this pin being secretly used? I don't know.
Now that I'm getting more experience with the gotchas with Arduino, I think the next project will be much easier.
#include "IRremote.h"
// ********** Light
int light_rgbPins[3];
boolean light_commonAnode;
boolean light_dbg;
boolean light_setup = false;
void setupLight(int redPin, int greenPin, int bluePin, boolean commonAnode, boolean dbgLightArg) {
light_setup = true;
light_rgbPins[0] = redPin;
light_rgbPins[1] = greenPin;
light_rgbPins[2] = bluePin;
light_commonAnode = commonAnode;
light_dbg = dbgLightArg;
for (int i = 0; i < 3; i++) pinMode(light_rgbPins[i], OUTPUT);
}
void light(int r, int g, int b) {
if (! light_setup) return;
analogWrite(light_rgbPins[0], light_commonAnode ? 255 - r : r);
analogWrite(light_rgbPins[1], light_commonAnode ? 255 - g : g);
analogWrite(light_rgbPins[2], light_commonAnode ? 255 - b : b);
if (light_dbg) {
Serial.print("speed ");
Serial.print(r);
Serial.print(" ");
Serial.print(g);
Serial.print(" ");
Serial.println(b);
}
}
// ********** Fan
int fan_enablePin;
int fan_fwdPin;
int fan_revPin;
int fan_minSpeed;
int fan_maxSpeed;
boolean fan_dbg;
boolean fan_setup = false;
void setupFan(int enablePinArg, int fwdPinArg, int revPinArg, int minSpeedArg, int maxSpeedArg, boolean dbgFanArg) {
fan_setup = true;
fan_enablePin = enablePinArg;
fan_fwdPin = fwdPinArg;
fan_revPin = revPinArg;
fan_minSpeed = minSpeedArg;
fan_maxSpeed = maxSpeedArg;
fan_dbg = dbgFanArg;
pinMode(fan_enablePin, OUTPUT);
pinMode(fan_fwdPin, OUTPUT);
pinMode(fan_revPin, OUTPUT);
}
void fan(boolean power, boolean fwd, int speed) {
if (! fan_setup) return;
speed = max(fan_minSpeed, speed);
speed = min(fan_maxSpeed, speed);
if (fwd) {
digitalWrite(fan_fwdPin, HIGH);
digitalWrite(fan_revPin, LOW);
} else {
digitalWrite(fan_fwdPin, LOW);
digitalWrite(fan_revPin, HIGH);
}
analogWrite(fan_enablePin, speed == fan_minSpeed || ! power ? 0 : speed);
if (fan_dbg) {
Serial.print("speed ");
Serial.println(speed);
}
}
// ********** Remote
int irr_pin;
IRrecv *irr_recv;
decode_results irr_results;
boolean irr_dbg;
boolean irr_setup = false;
boolean irr_blink;
#define R_NULL -1
#define R_ZERO 0
#define R_NINE 9
#define R_POWER 10
#define R_VOL_UP 11
#define R_VOL_DN 12
#define R_REV 13
#define R_FFWD 14
struct irr_key {
int symbol;
long unsigned int code;
};
struct irr_key irr_keys[] = {
{ R_VOL_UP, 0xFF629D },
{ R_VOL_DN, 0xFFA857 },
{ R_POWER, 0xFFA25D },
{ R_ZERO, 0xFF6897 },
{ R_ZERO + 1, 0xFF30CF },
{ R_ZERO + 2, 0xFF18E7 },
{ R_ZERO + 3, 0xFF7A85 },
{ R_ZERO + 4, 0xFF10EF },
{ R_ZERO + 5, 0xFF38C7 },
{ R_ZERO + 6, 0xFF5AA5 },
{ R_ZERO + 7, 0xFF42BD },
{ R_ZERO + 8, 0xFF4AB5 },
{ R_ZERO + 9, 0xFF52AD },
{ R_REV, 0xFF22DD },
{ R_FFWD, 0xFFC23D }
};
int irr_keysCt = sizeof(irr_keys) / sizeof(irr_keys[0]);
void setupIRRemote(int irRemotePinArg, boolean blink, boolean dbgIRRemoteArg) {
irr_setup = true;
irr_pin = irRemotePinArg;
irr_blink = blink;
IRrecv recv = IRrecv(irr_pin);
irr_recv = &recv;
irr_recv->enableIRIn();
if (irr_blink) pinMode(LED_BUILTIN, OUTPUT);
irr_dbg = dbgIRRemoteArg;
}
int irRemote() {
int key = R_NULL;
if (! irr_setup) return key;
if (irr_recv->decode(&irr_results)) {
for (int i = 0; i < irr_keysCt; i++) {
if (irr_results.value == irr_keys[i].code) {
key = irr_keys[i].symbol;
if (irr_blink) {
digitalWrite(LED_BUILTIN, HIGH);
delay(250);
digitalWrite(LED_BUILTIN, LOW);
}
break;
}
}
irr_recv->resume(); // receive the next value
if (irr_dbg) {
Serial.print("key ");
Serial.print(key);
Serial.print(" ");
Serial.println(irr_results.value, HEX);
}
}
return key;
}
// ********** Program-specific
// Fan
int speed = 210;
int speedDelta = 5;
boolean power = false;
boolean fwd = true;
int minSpeed = 50;
int maxSpeed = 255;
int speedMultiplier = (maxSpeed - minSpeed) / 9.0 + 0.5;
// Light
const float pi = 3.141592654;
float d2r(float d) {
return d * pi / 180.0;
}
float rad = 0.0;
float rShift = 0.0;
float gShift = d2r(120.0);
float bShift = d2r(240.0);
float radDelta = 2.0 * pi / 600.0;
int lightLevel = 255;
void setup() {
setupLight(13, 12, 11, false, false);
light(255, 0, 0);
setupFan(5, 3, 4, minSpeed, maxSpeed, false);
fan(power, fwd, speed);
setupIRRemote(2, true, false);
Serial.begin(9600);
}
void loop() {
if (! power) {
light(255, 0, 0);
} else {
light(
(cos(rad + rShift) + 1.0) / 2.0 * lightLevel,
(cos(rad + gShift) + 1.0) / 2.0 * lightLevel,
(cos(rad + bShift) + 1.0) / 2.0 * lightLevel);
}
rad += radDelta;
int key = irRemote();
if (key != R_NULL) {
boolean setspeed = false;
if (key >= 0 && key <= 9) {
speed = minSpeed + key * speedMultiplier;
setspeed = true;
} else {
switch(key) {
case R_VOL_UP:
speed += speedDelta;
if (speed > maxSpeed) speed = maxSpeed;
setspeed = true;
break;
case R_VOL_DN:
speed -= speedDelta;
if (speed < minSpeed) speed = minSpeed;
setspeed = true;
break;
case R_POWER:
power = ! power;
setspeed = true;
break;
case R_REV:
fwd = false;
setspeed = true;
break;
case R_FFWD:
fwd = true;
setspeed = true;
break;
}
}
if (setspeed) {
fan(power, fwd, speed);
}
}
delay(10);
}
The Arduino IDE is not very good so I decided to try an Arduino plugin for Eclipse. After not having luck with Sloeber, I tried Eclipse C++ IDE for Arduino 2.0. I had much better success with this and thought the tutorial was very helpful. Of course I had a few gotchas that I had to work out.
First, I was getting a make error about no target for "/Users/Mike". This was obviously something to do with spaces in path names as my user directory is "/Users/Mike Barborak". It turns out this path was coming from the location of the Arduino home which is by default put in your users directory on Windows 10 at .arduinocdt. I moved this folder to a place without spaces (/arduino_ws/.arduinocdt) and let Eclipse know via Window > Preferences > C/C++ > Arduino. After that, I was able to follow along with the tuorial no problem.
Next, I wanted to do something with this 2.8" touch screen that I bought for $15! Fortunately, it came with libraries to make it easy to use. Unfortunately, the Eclipse plugin doesn't have a way to import arbitrary libraries like the Arduino IDE does. What ended up working for me was to copy the library folders (unzip if necessary) to .arduinocdt/libraries. If a library folder contained library.properties then that seemed to be all that was needed. But if it wasn't there then I had to create it before the libraries showed up in Eclipse at Project > Properties > Libraries. Here's the library.properties file I created for Elegoo's TouchScreen library with an incorrect url and other warts. I made a very similar one for Elegoo_TFTLCD.
name=Elegoo TouchScreen Library
version=1.0.2
author=Elegoo
maintainer=Elegoo <info@Elegoo.com>
sentence=Elegoo
paragraph=Elegoo
category=Display
url=https://github.com/Elegoo/Elegoo-GFX-Library
architectures=*
After this I was pretty much able to take the example code that came with the screen and run it without modification. (The example code had forward declared functions that the Eclipse compiler complained about.)
Before getting the touchscreen to work, I had played with a library called Ultrasonic that made it easy to use the HC-SR04 distance sensor that came with the Arduino starter kit. So now I wanted to see if I could combine these two things. I decided to make a portable distance measurer. You can see what I came up with the in picture and video below. What I thought was pretty cool was how the distance sensor plugged directly into the Arduino digital I/O pins and got its power from them. (In the code I just set the ground pin to LOW and the voltage pin to HIGH. Of course!)
#include <Elegoo_GFX.h> // Core graphics library
#include <Elegoo_TFTLCD.h> // Hardware-specific library
#include <Ultrasonic.h>
// Assign human-readable names to some common 16-bit color values:
#define BLACK 0x0000
#define BLUE 0x001F
#define RED 0xF800
#define GREEN 0x07E0
#define CYAN 0x07FF
#define MAGENTA 0xF81F
#define YELLOW 0xFFE0
#define WHITE 0xFFFF
Elegoo_TFTLCD tft(A3, A2, A1, A0, A4);
Ultrasonic us(39, 37, 40000UL); // (Trig PIN,Echo PIN, timeout)
void setup(void) {
Serial.begin(115200);
pinMode(41, OUTPUT); // VCC pin
pinMode(35, OUTPUT); // GND ping
digitalWrite(41, HIGH); // VCC +5V mode
digitalWrite(35, LOW); // GND mode
tft.reset();
uint16_t identifier = tft.readID();
if (identifier == 0x0101) {
identifier = 0x9341;
Serial.println(F("Found 0x9341 LCD driver"));
}
tft.begin(identifier);
tft.fillScreen(BLACK);
tft.setTextColor(GREEN);
tft.setTextSize(5);
}
void loop(void) {
unsigned int cms = us.distanceRead();
float insExact = 0.393701 * cms;
int ft = insExact / 12;
int ins = (int) insExact % 12;
Serial.print("Dist. ");
Serial.print(ft);
Serial.print("'");
Serial.print(ins);
Serial.println("\"");
tft.fillRect(0, 0, 240, 40, BLACK);
tft.setCursor(0, 0);
tft.print(ft);
tft.print("'");
tft.print(ins);
tft.print("\"");
delay(100);
}